トップ 履歴 一覧 カテゴリ ソース 検索 ヘルプ RSS ログイン

Source/Bat/OraExpImp

INDEX

Oracle DB エクスポート・インポート バッチ

昔、プロジェクトで支援用として作った、Oracle のエクスポート・インポートのバッチ。

最初、テーブルモードの時のテーブルのリストをバッチファイル内に書いてたら、外部ファイルにしろって事で、対象テーブルを外部ファイルにしたバージョンも。

※プロジェクト名とか接続情報とか適当に変更してます。また、実行日時の取得処理の関係でWindows2000専用です(ちょっといじればXPとかでも使えるけど)。

Oracle DB エクスポートバッチ

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
 
@ECHO OFF
ECHO  *****************************************************************************
ECHO  *      システム：○○○○○○○○システム                                   *
ECHO  *  サブシステム：Oracle DB Export バッチ                                    *
ECHO  *                                  MakeDate:2003/10/06   Creator:T.Imamura  *
ECHO  *****************************************************************************
REM 
REM このバッチファイルは、OracleのDBデータをエクスポートするバッチファイルです。
REM 
REM 全体,ユーザ.テーブル単位でのエクスポートが可能です。
REM エクスポートファイル名には、実行した日時が付加されます。
REM 　　　　(エクスポートファイル接頭文字列)_YYYYMMDDhhmmss.DMP
REM 
REM このバッチプログラムはWindows2000(XP)専用です。(Win9x系では動きません)
REM 確認用の一時停止が不要なら、"PAUSE"行をコメントアウト("REM "を付ける)してください。
REM 

REM ******* 環境設定 *******     ※実行前に確認すること！
REM エクスポートファイル接頭文字列
SET PRE_EXP_FILE=EXPDAT_scotto

REM **** 接続設定 ****
REM Oracle 接続サービス名
SET ORACLE_SID=demo
REM Oracle ユーザ名
SET ORACLE_USER=scotto
REM Oracle パスワード
SET ORACLE_PASS=tiger

REM **** エクスポート設定 ****
REM エクスポートモード(F:全体/U:ユーザ/T:テーブル)
SET MODE=F
REM エクスポート対象リスト(カンマ区切り)　ユーザ/テーブルモードのみ
SET LIST=scotto
REM 権限のエクスポート(Y/n)
SET GRANTS=Y
REM 索引のエクスポート(Y/n)
SET INDEXES=Y
REM 制約のエクスポート(Y/n)
SET CONSTRAINTS=Y
REM 表データ行のエクスポート(Y/n)
SET ROWS=Y
REM エクステントの圧縮(Y/N)
SET COMPRESS=Y

REM ******* 環境設定 ******* 通常はここまで *******
REM 実行日時の取得 FORMAT="YYYYMMDDhhmmss" 
SET NOWTIMES=%DATE:~2,4%%DATE:~7,2%%DATE:~10,2%%TIME:~0,2%%TIME:~3,2%%TIME:~6,2%

REM OracleエクスポートプログラムEXE名(必要時はパスも、通常は変更不用)
SET ORAEXP_EXEC=EXP
REM エクスポートファイルの設定　接頭文字列、実行日時、拡張子の組立
SET EXP_FILE=%PRE_EXP_FILE%_%NOWTIMES%.DMP
REM エクスポート結果ログファイル
SET EXP_LOG_FILE=oracle_export.log

REM エクスポートファイル存在確認
IF EXIST %EXP_FILE% GOTO FoundExpFile

REM ***********************************
REM  エクスポートモード設定処理
REM ***********************************
IF "%MODE%"=="F" GOTO MODE_FULL
IF "%MODE%"=="f" GOTO MODE_FULL
IF "%MODE%"=="U" GOTO MODE_USER
IF "%MODE%"=="u" GOTO MODE_USER
IF "%MODE%"=="T" GOTO MODE_TABLE
IF "%MODE%"=="t" GOTO MODE_TABLE
GOTO ModeErr

REM ファイル全体のエクスポート(Y/N)
:MODE_FULL
SET MODES=FULL=Y
ECHO エクスポートモード　　：全データベース
GOTO MODE_END
REM 所有者のユーザー名リスト(USER1[,USER2[,....]])
:MODE_USER
SET MODES=OWNER=(%LIST%)
ECHO エクスポートモード　　：ユーザ単位　対象ユーザ：%LIST%
GOTO MODE_END
REM 表名のリスト(TABLE1[,TABLE2[,....]])
:MODE_TABLE
SET MODES=TABLES=(%LIST%)
ECHO エクスポートモード　　：テーブル単位　対象テーブル：%LIST%
GOTO MODE_END
REM モード設定処理 終わり
:MODE_END

ECHO エクスポートオプション：権限=%GRANTS% 牽引=%INDEXES% 表データ=%ROWS% 圧縮=%COMPRESS%
ECHO エクスポートファイル　：%EXP_FILE%

REM 開始メッセージ
ECHO.
ECHO エクスポートします。よろしいですか？
PAUSE
ECHO.
ECHO エクスポート中.....

REM 開始時刻の出力
ECHO ○○○○○○○○システム Oracle DB Export>%EXP_LOG_FILE%
ECHO 開始時刻 %DATE% %TIME%>>%EXP_LOG_FILE%

REM エクスポート処理
rem %ORAEXP_EXEC% %ORACLE_USER%/%ORACLE_PASS%@%ORACLE_SID% %MODES% FILE=%EXP_FILE% LOG=%EXP_LOG_FILE% GRANTS=%GRANTS% INDEXES=%INDEXES% ROWS=%ROWS% COMPRESS=%COMPRESS%
%ORAEXP_EXEC% %ORACLE_USER%/%ORACLE_PASS%@%ORACLE_SID% %MODES% FILE=%EXP_FILE% GRANTS=%GRANTS% INDEXES=%INDEXES% ROWS=%ROWS% COMPRESS=%COMPRESS% CONSTRAINTS=%CONSTRAINTS%>>%EXP_LOG_FILE% 2>&1

REM 終了時刻の出力
ECHO.>>%EXP_LOG_FILE%
ECHO 終了時刻 %DATE% %TIME%>>%EXP_LOG_FILE%

ECHO エクスポートが終了しました。
ECHO エクスポートログ%EXP_LOG_FILE%を確認してください。
GOTO END
REM ***********************************
REM  エラー処理
REM ***********************************
:ModeErr
ECHO エクスポートモードの指定が不正です。確認してください。 MODE=%MODE%
GOTO END
:FoundExpFile
ECHO エクスポートファイル(%EXP_FILE%)がすでに存在します。
GOTO END

REM ***********************************
REM  終了
REM ***********************************
:END
PAUSE

Oracle DB インポートバッチ

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
 
@ECHO OFF
ECHO  *****************************************************************************
ECHO  *      システム：○○○○○○○○システム                                   *
ECHO  *  サブシステム：Oracle DB Import バッチ                                    *
ECHO  *                                  MakeDate:2003/10/06   Creator:T.Imamura  *
ECHO  *****************************************************************************
REM 
REM このバッチファイルは、OracleのDBデータをインポートするバッチファイルです。
REM 
REM 
REM このバッチプログラムはWindows2000(XP)専用です。(Win9x系では動きません)
REM 確認用の一時停止が不要なら、"PAUSE"行をコメントアウト("REM "を付ける)してください。
REM 

REM ******* 環境設定 *******     ※実行前に確認すること！
REM インポートファイルの設定
SET IMP_FILE=EXPDAT_scotto_20031006171220.DMP

REM **** 接続設定 ****
REM Oracle 接続サービス名
SET ORACLE_SID=demo
REM Oracle ユーザ名
SET ORACLE_USER=scotto
REM Oracle パスワード
SET ORACLE_PASS=tiger

REM **** インポート設定 ****
REM オブジェクト作成時エラー無視(y/N)
SET IGNORE=N
REM 権限のインポート(Y/n)
SET GRANTS=Y
REM 索引のインポート(Y/n)
SET INDEXES=Y
REM 制約のエクスポート(Y/n)
SET CONSTRAINTS=Y
REM 表データ行のインポート(Y/n)
SET ROWS=Y
REM すべてのデータをのインポート(Y/N)
SET FULL=Y
REM インポート対象ユーザリスト(FULL=Yの場合は=以降書かない)
SET FROMUSER=
REM インポート先ユーザリスト(FULL=Yの場合は=以降書かない)
SET TOUSER=
REM インポート対象テーブルリスト(すべての表は"*")(FULL=Yの場合は=以降書かない)
SET TABLES=

REM エクスポートファイルの内容表示(Y/N)
SET SHOW=Y


REM OracleインポートプログラムEXE名(必要時はパスも、通常は変更不用)
SET ORAIMP_EXEC=IMP
REM インポート結果ログファイル
SET IMP_LOG_FILE=oracle_import.log

REM インポートファイル存在確認
IF NOT EXIST %IMP_FILE% GOTO NotFoundImpFile

REM インポートモード確認
IF "%FULL%"=="Y" GOTO MODE_FULL
IF "%FULL%"=="y" GOTO MODE_FULL
IF "%FULL%"=="N" GOTO MODE_USER
IF "%FULL%"=="n" GOTO MODE_USER
GOTO ModeErr

:MODE_FULL
IF NOT "%FROMUSER%"=="" GOTO ModeErr
IF NOT "%TOUSER%"  =="" GOTO ModeErr
IF NOT "%TABLES%"  =="" GOTO ModeErr
SET MODES=FULL=Y
ECHO インポートモード　　：全データベース
GOTO MODE_END
:MODE_USER
SET MODES=FULL=N
IF NOT "%FROMUSER%"=="" SET MODES=%MODES% FROMUSER=%FROMUSER%
IF NOT "%TOUSER%"  =="" SET MODES=%MODES% TOUSER=%TOUSER%
IF NOT "%TABLES%"  =="" SET MODES=%MODES% TABLES=%TABLES%
IF "%MODES%"=="FULL=N" GOTO ModeErr
ECHO インポートモード　　：ユーザ or テーブル
ECHO                     ：%MODES%
GOTO MODE_END

REM モード確認 終わり
:MODE_END


ECHO インポートオプション：権限=%GRANTS% 牽引=%INDEXES% 表データ=%ROWS%
ECHO                     ：エラー無視=%IGNORE% 表示のみ=%SHOW%
ECHO インポートファイル　：%IMP_FILE%

REM 開始メッセージ
ECHO.
ECHO インポートします。よろしいですか？
PAUSE
ECHO.
ECHO インポート中.....

REM 開始時刻の出力
ECHO ○○○○○○○○システム Oracle DB Import>%IMP_LOG_FILE%
ECHO 開始時刻 %DATE% %TIME%>>%IMP_LOG_FILE%

REM インポート処理
REM %ORAIMP_EXEC% %ORACLE_USER%/%ORACLE_PASS%@%ORACLE_SID% %MODES% FILE=%IMP_FILE% LOG=%EXP_LOG_FILE% GRANTS=%GRANTS% INDEXES=%INDEXES% ROWS=%ROWS% IGNORE=%IGNORE% SHOW=%SHOW%
%ORAIMP_EXEC% %ORACLE_USER%/%ORACLE_PASS%@%ORACLE_SID% %MODES% FILE=%IMP_FILE% GRANTS=%GRANTS% INDEXES=%INDEXES% ROWS=%ROWS% IGNORE=%IGNORE% CONSTRAINTS=%CONSTRAINTS% SHOW=%SHOW% >>%IMP_LOG_FILE% 2>&1

REM 終了時刻の出力
ECHO.>>%IMP_LOG_FILE%
ECHO 終了時刻 %DATE% %TIME%>>%IMP_LOG_FILE%

ECHO インポートが終了しました。
ECHO インポートログ%IMP_LOG_FILE%を確認してください。
GOTO END
REM ***********************************
REM  エラー処理
REM ***********************************
:NotFoundImpFile
ECHO インポートファイル(%IMP_FILE%)が見つかりません。
GOTO END
:ModeErr
ECHO インポートモードの指定に矛盾があります。
GOTO END

REM ***********************************
REM  終了
REM ***********************************
:END
PAUSE

Oracle DB エクスポートバッチ2

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
 
@ECHO OFF
ECHO  *****************************************************************************
ECHO  *      システム：○○○○○○○○システム                                   *
ECHO  *  サブシステム：Oracle DB Table Export バッチ                              *
ECHO  *                                  MakeDate:2003/10/06   Creator:T.Imamura  *
ECHO  *****************************************************************************
REM 
REM このバッチファイルは、OracleのDBデータをエクスポートするバッチファイルです。
REM 
REM テーブル単位でのエクスポートが可能です。
REM エクスポートファイル名には、実行した日時が付加されます。
REM 　　　　(エクスポートファイル接頭文字列)_YYYYMMDDhhmmss.DMP
REM 
REM テーブル対象のエクスポートは「エクスポート対象テーブルリスト(DBTB_LIST.TXT)」に
REM 列挙されれいるものを対象テーブルとしてエクスポートを行います。
REM 
REM 
REM ==起動コマンドは「CMD.EXE /V:ON /C DBEXPTB.BAT」として起動してください。==
REM *SETLOCAL及びENDLOCALコマンドを利用する様に変更したので通常と同じでよいです。*
REM 
REM このバッチプログラムはWindows2000(XP)専用です。(Win9x系では動きません)
REM 確認用の一時停止が不要なら、"PAUSE"行をコメントアウト("REM "を付ける)してください。
REM 

REM 遅延環境変数の展開を有効に
SETLOCAL ENABLEDELAYEDEXPANSION
REM ******* 環境設定 *******     ※実行前に確認すること！
REM エクスポートファイル接頭文字列
SET PRE_EXP_FILE=EXPDAT_scotto
REM テーブルリストファイルの設定
SET DBTBLIST=DBTB_LIST.TXT

REM **** 接続設定 ****
REM Oracle 接続サービス名
SET ORACLE_SID=demo
REM Oracle ユーザ名
SET ORACLE_USER=scotto
REM Oracle パスワード
SET ORACLE_PASS=tiger

REM **** エクスポート設定 ****
REM 権限のエクスポート(Y/n)
SET GRANTS=Y
REM 索引のエクスポート(Y/n)
SET INDEXES=Y
REM 制約のエクスポート(Y/n)
SET CONSTRAINTS=Y
REM 表データ行のエクスポート(Y/n)
SET ROWS=Y
REM エクステントの圧縮(Y/N)
SET COMPRESS=Y

REM ******* 環境設定 ******* 通常はここまで *******
REM 実行日時の取得 FORMAT="YYYYMMDDhhmmss" 
SET NOWTIMES=%DATE:~2,4%%DATE:~7,2%%DATE:~10,2%%TIME:~0,2%%TIME:~3,2%%TIME:~6,2%

REM OracleエクスポートプログラムEXE名(必要時はパスも、通常は変更不用)
SET ORAEXP_EXEC=EXP
REM エクスポートファイルの設定　接頭文字列、実行日時、拡張子の組立
SET EXP_FILE=%PRE_EXP_FILE%_%NOWTIMES%.DMP
REM エクスポート結果ログファイル
SET EXP_LOG_FILE=oracle_export.log

REM エクスポートファイル存在確認
IF EXIST %EXP_FILE% GOTO FoundExpFile

REM 遅延環境変数の展開が有効チェック
SET VAR=BEFORE
IF "%VAR%" == "BEFORE" (
  SET VAR=AFTER
  IF "!VAR!" == "AFTER" GOTO DELAY_OK
)
GOTO DELAY_NG
:DELAY_OK

REM ***********************************
REM  エクスポートモード設定処理
REM ***********************************
REM 表名のリスト(TABLE1[,TABLE2[,....]])
:MODE_TABLE
IF NOT EXIST %DBTBLIST% GOTO NotFoundListFile
SET LIST=
FOR /F %%f IN (%DBTBLIST%) do set LIST=!LIST!,%%f
SET LIST=%LIST:~1%
SET MODES=TABLES=(%LIST%)
ECHO エクスポートモード　　：テーブル単位　対象テーブル：%LIST%
GOTO MODE_END
REM モード設定処理 終わり
:MODE_END

ECHO エクスポートオプション：権限=%GRANTS% 牽引=%INDEXES% 表データ=%ROWS% 圧縮=%COMPRESS%
ECHO エクスポートファイル　：%EXP_FILE%

REM 開始メッセージ
ECHO.
ECHO エクスポートします。よろしいですか？
PAUSE
ECHO.
ECHO エクスポート中.....

REM 開始時刻の出力
ECHO ○○○○○○○○システム Oracle DB Export>%EXP_LOG_FILE%
ECHO 開始時刻 %DATE% %TIME%>>%EXP_LOG_FILE%

REM エクスポート処理
rem %ORAEXP_EXEC% %ORACLE_USER%/%ORACLE_PASS%@%ORACLE_SID% %MODES% FILE=%EXP_FILE% LOG=%EXP_LOG_FILE% GRANTS=%GRANTS% INDEXES=%INDEXES% ROWS=%ROWS% COMPRESS=%COMPRESS%
%ORAEXP_EXEC% %ORACLE_USER%/%ORACLE_PASS%@%ORACLE_SID% %MODES% FILE=%EXP_FILE% GRANTS=%GRANTS% INDEXES=%INDEXES% ROWS=%ROWS% COMPRESS=%COMPRESS% CONSTRAINTS=%CONSTRAINTS%>>%EXP_LOG_FILE% 2>&1

REM 終了時刻の出力
ECHO.>>%EXP_LOG_FILE%
ECHO 終了時刻 %DATE% %TIME%>>%EXP_LOG_FILE%

ECHO エクスポートが終了しました。
ECHO エクスポートログ%EXP_LOG_FILE%を確認してください。
GOTO END
REM ***********************************
REM  エラー処理
REM ***********************************
:ModeErr
ECHO エクスポートモードの指定が不正です。確認してください。 MODE=%MODE%
GOTO END
:FoundExpFile
ECHO エクスポートファイル(%EXP_FILE%)がすでに存在します。
GOTO END
:NotFoundListFile
ECHO エクスポート対象テーブルリストファイル(%DBTBLIST%)が見つかりません。
GOTO END
:DELAY_NG
ECHO 遅延環境変数の展開が有効になっていません。
ECHO 「CMD.EXE /V:ON /C DBEXPTB.BAT」として起動してください。
GOTO END

REM ***********************************
REM  終了
REM ***********************************
:END
ENDLOCAL
PAUSE

Oracle DB インポートバッチ2

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
 
@ECHO OFF
ECHO  *****************************************************************************
ECHO  *      システム：○○○○○○○○システム                                   *
ECHO  *  サブシステム：Oracle DB Table Import バッチ                              *
ECHO  *                                  MakeDate:2003/10/06   Creator:T.Imamura  *
ECHO  *****************************************************************************
REM 
REM このバッチファイルは、OracleのDBデータを表単位でインポートするバッチファイルです。
REM 
REM テーブル対象のインポートは「インポート対象テーブルリスト(DBTB_LIST.TXT)」に
REM 列挙されれいるものを対象テーブルとしてインポートを行います。
REM 
REM 
REM ==起動コマンドは「CMD.EXE /V:ON /C DBEXPTB.BAT」として起動してください。==
REM *SETLOCAL及びENDLOCALコマンドを利用する様に変更したので通常と同じでよいです。*
REM 
REM このバッチプログラムはWindows2000(XP)専用です。(Win9x系では動きません)
REM 確認用の一時停止が不要なら、"PAUSE"行をコメントアウト("REM "を付ける)してください。
REM 

REM 遅延環境変数の展開を有効に
SETLOCAL ENABLEDELAYEDEXPANSION
REM ******* 環境設定 *******     ※実行前に確認すること！
REM インポートファイルの設定
SET IMP_FILE=EXPDAT_scotto_20031006195504.DMP
REM テーブルリストファイルの設定
SET DBTBLIST=DBTB_LIST.TXT

REM **** 接続設定 ****
REM Oracle 接続サービス名
SET ORACLE_SID=demo
REM Oracle ユーザ名
SET ORACLE_USER=scotto
REM Oracle パスワード
SET ORACLE_PASS=tiger

REM **** インポート設定 ****
REM オブジェクト作成時エラー無視(y/N)
SET IGNORE=N
REM 権限のインポート(Y/n)
SET GRANTS=Y
REM 索引のインポート(Y/n)
SET INDEXES=Y
REM 制約のエクスポート(Y/n)
SET CONSTRAINTS=Y
REM 表データ行のインポート(Y/n)
SET ROWS=Y
REM インポート対象ユーザリスト(FULL=Yの場合は=以降書かない)
SET FROMUSER=
REM インポート先ユーザリスト(FULL=Yの場合は=以降書かない)
SET TOUSER=
REM インポート対象テーブルリスト(すべての表は"*")(FULL=Yの場合は=以降書かない)
REM SET TABLES=

REM エクスポートファイルの内容表示(Y/N)
SET SHOW=Y

REM ******* 環境設定 ******* 通常はここまで *******
REM OracleインポートプログラムEXE名(必要時はパスも、通常は変更不用)
SET ORAIMP_EXEC=IMP
REM インポート結果ログファイル
SET IMP_LOG_FILE=oracle_import.log

REM インポートファイル存在確認
IF NOT EXIST %IMP_FILE% GOTO NotFoundImpFile

REM 遅延環境変数の展開が有効チェック
SET VAR=BEFORE
IF "%VAR%" == "BEFORE" (
  SET VAR=AFTER
  IF "!VAR!" == "AFTER" GOTO DELAY_OK
)
GOTO DELAY_NG
:DELAY_OK

REM インポートモード確認
IF NOT EXIST %DBTBLIST% GOTO NotFoundListFile
SET LIST=
FOR /F %%f IN (%DBTBLIST%) do set LIST=!LIST!,%%f
SET LIST=%LIST:~1%
SET MODES=TABLES=(%LIST%)
IF NOT "%FROMUSER%"=="" SET MODES=%MODES% FROMUSER=%FROMUSER%
IF NOT "%TOUSER%"  =="" SET MODES=%MODES% TOUSER=%TOUSER%
ECHO インポートモード　　：テーブル単位　対象テーブル：%LIST%
ECHO                     ：%MODES%
ECHO インポートオプション：権限=%GRANTS% 牽引=%INDEXES% 表データ=%ROWS%
ECHO                     ：エラー無視=%IGNORE% 表示のみ=%SHOW%
ECHO インポートファイル　：%IMP_FILE%

REM 開始メッセージ
ECHO.
ECHO インポートします。よろしいですか？
PAUSE
ECHO.
ECHO インポート中.....

REM 開始時刻の出力
ECHO ○○○○○○○○システム Oracle DB Import>%IMP_LOG_FILE%
ECHO 開始時刻 %DATE% %TIME%>>%IMP_LOG_FILE%

REM インポート処理
REM %ORAIMP_EXEC% %ORACLE_USER%/%ORACLE_PASS%@%ORACLE_SID% %MODES% FILE=%IMP_FILE% LOG=%EXP_LOG_FILE% GRANTS=%GRANTS% INDEXES=%INDEXES% ROWS=%ROWS% IGNORE=%IGNORE% SHOW=%SHOW%
%ORAIMP_EXEC% %ORACLE_USER%/%ORACLE_PASS%@%ORACLE_SID% %MODES% FILE=%IMP_FILE% GRANTS=%GRANTS% INDEXES=%INDEXES% ROWS=%ROWS% IGNORE=%IGNORE% CONSTRAINTS=%CONSTRAINTS% SHOW=%SHOW% >>%IMP_LOG_FILE% 2>&1

REM 終了時刻の出力
ECHO.>>%IMP_LOG_FILE%
ECHO 終了時刻 %DATE% %TIME%>>%IMP_LOG_FILE%

ECHO インポートが終了しました。
ECHO インポートログ%IMP_LOG_FILE%を確認してください。
GOTO END
REM ***********************************
REM  エラー処理
REM ***********************************
:NotFoundImpFile
ECHO インポートファイル(%IMP_FILE%)が見つかりません。
GOTO END
:ModeErr
ECHO インポートモードの指定に矛盾があります。
GOTO END
:NotFoundListFile
ECHO エクスポート対象テーブルリストファイル(%DBTBLIST%)が見つかりません。
GOTO END
:DELAY_NG
ECHO 遅延環境変数の展開が有効になっていません。
ECHO 「CMD.EXE /V:ON /C DBIMPTB.BAT」として起動してください。
GOTO END

REM ***********************************
REM  終了
REM ***********************************
:END
ENDLOCAL
PAUSE

対象テーブルリストファイル

LMD000M
LMD010M
LMD020M
LMD030M
LMD040M

最終更新時間：2009年02月07日 18時45分20秒　指摘や意見などあればSandBoxのBBSへ。

DBEXP.BAT DBEXPTB.BAT DBIMP.BAT DBIMPTB.BAT

ようこそ、ゲスト さん

メニュー

検索

キーワード

最新

2026/6/1

2026/5/23

2026/5/20

2026/5/19

2026/5/17

Copyright (C) 2002 たけ
Powered by FreeStyleWiki3.6.5 with Perl5.016003